PROGRAM HRW_JIMMY
c     -----------------
c     Example main program to run JIMMY at LHC with
c     100 GeV jets plus MI underlying event. Change IPROC
c     do do other stuff.
c     Jon Butterworth 18/03/04
c     --------------------------------
c     HERWIG/JIMMY COMMONS. HERWIG COMMON INCLUDES AN IMPLICIT NONE.
      INCLUDE 'HERWIG65.INC'
      INCLUDE 'JIMMY.INC'

      LOGICAL ABORT
      INTEGER LOOP
      DOUBLE PRECISION HWRSET

c     =============================================================
c
c       LHC running with nominal energies
c
c     =============================================================

      WRITE (*,*)
      WRITE (*,*) '================================================'
      WRITE (*,*) ' LHC running with nominal energies'
      WRITE (*,*) '================================================'
      
c     Set beam energies
      PART1='P  '
      PART2='P  '
      PBEAM1=7000.0
      PBEAM2=7000.0
      
c     QCD 2->2 with S.U.E suppressed
      IPROC=11500

C     HERWIG initialization
      CALL HWIGIN
C     JIMMY initialization
      CALL JIMMIN

c      MODPDF(1)=46
c      AUTPDF(1)='CTEQ'
c      MODPDF(2)=46
c      AUTPDF(2)='CTEQ'

c     Minimum PT of the hardest scatter
      PTMIN=100.

c     Minimum PT of secondary scatters
      PTJIM=2.5

C---  Turn MI on(1) or off(0)
      MSFLAG=1

C     More initialization.
      CALL HWUINC
      CALL HWEINI            
      CALL JMINIT

      MAXEV=10000
      MAXER=MAXEV/5

C     Initialise your histograms here.
      CALL HWABEG

C     Loop over events.
      DO LOOP=1,MAXEV
 50      CONTINUE
         
C---  INITIALISE EVENT
         CALL HWUINE
C---  GENERATE HARD SUBPROCESS
         CALL HWEPRO
C---  GENERATE PARTON CASCADES
         CALL HWBGEN
C---  GENERATE MULTIPARTON INTERACTIONS
         IF (MSFLAG.EQ.1) THEN
            CALL HWMSCT(ABORT)
            IF (ABORT) GOTO 50
         ENDIF
C---  DO HEAVY QUARK DECAYS
         CALL HWDHOB
C---  DO CLUSTER HADRONIZATION
         CALL HWCFOR
C---  DO CLUSTER DECAY
         CALL HWCDEC
C---  DO UNSTABLE PARTICLE DECAYS
         CALL HWDHAD
C---  DO HEAVY FLAVOUR DECAYS
         CALL HWDHVY
C---  ADD SOFT UNDERLYING EVENT IF NEEDED
         CALL HWMEVT
C---  FINALISE EVENT
         CALL HWUFNE
         
         IF (IERROR.NE.0) GOTO 50
         
         IF (mod(LOOP,1000).eq.0) THEN
            PRINT*,"Event ",LOOP
         ENDIF

c     Fill your histograms here.
      CALL HWANAL


         
      ENDDO
      
C     Finish off Herwig Routines
      CALL HWEFIN
C     Finish off JIMMY
      CALL JMEFIN
      
C     Close & ouput histograms.here
      CALL HWAEND
      END
      SUBROUTINE HWABEG
      END
      SUBROUTINE HWANAL
      END
      SUBROUTINE HWAEND
      END